extends Node2D

@onready var witch = get_node("/root/Game/Witch")
@onready var player = get_node("/root/Game/Player")
var fireball = preload("res://scenes/fireball.tscn")
var throwing_knife = preload("res://scenes/throwing_knive.tscn")
var cauldron
var available_perks: Array[Perk] = []
var fireball_aoe_enabled = false
var throwing_knife_enabled = false
var throwing_knife_cooldown: float = 2.0
var throwing_knife_count: int = 1
var _knife_timer: float = 0.0

var spellbook_scene = preload("res://scenes/spellbook.tscn")
var spellbook_count: int = 0
var spellbook_damage: int = 12
var spellbook_speed: float = 1.5
const SPELLBOOK_RADIUS: float = 60.0
var _spellbook_angle: float = 0.0
var _spellbooks: Array = []

func _ready() -> void:
	cauldron = witch.get_node("CauldronBar")
	var dsh = Perk.new()
	dsh.name = "Double Shuriken"
	dsh.description = "Throw two shurikens instead of one"
	dsh.effect = double_shuriken
	available_perks.append(dsh)
	var faoe = Perk.new()
	faoe.name = "AOE Fireball"
	faoe.description = "Fireballs spawn an explosion on contact"
	faoe.effect = fireball_aoe
	available_perks.append(faoe)
	var bexp = Perk.new()
	bexp.name = "Brew Explosion"
	bexp.description = "The Witch casts an explosion on finishing a brew"
	bexp.effect = brew_explosion
	available_perks.append(bexp)
	var tk = Perk.new()
	tk.name = "Throwing Knife"
	tk.description = "Automatically throw a knife at the nearest enemy every second"
	tk.effect = enable_throwing_knife
	available_perks.append(tk)
	var sb = Perk.new()
	sb.name = "Spellbook"
	sb.description = "A spellbook orbits the witch, dealing 12 damage to enemies it touches"
	sb.effect = unlock_spellbook
	available_perks.append(sb)

func _process(delta: float) -> void:
	if throwing_knife_enabled:
		_knife_timer += delta
		if _knife_timer >= throwing_knife_cooldown:
			_knife_timer = 0.0
			_shoot_throwing_knife()
	if spellbook_count > 0:
		_spellbook_angle += spellbook_speed * delta
		for i in range(_spellbooks.size()):
			var offset = (TAU / _spellbooks.size()) * i
			_spellbooks[i].global_position = witch.global_position + Vector2(cos(_spellbook_angle + offset), sin(_spellbook_angle + offset)) * SPELLBOOK_RADIUS

func double_shuriken():
	witch.shuriken_count = 2

func fireball_aoe():
	fireball_aoe_enabled = true

func brew_explosion():
	cauldron.brew_explosion = true

func enable_throwing_knife():
	throwing_knife_enabled = true
	var upg = Perk.new()
	upg.name = "Knife Cooldown"
	upg.description = "Reduce throwing knife cooldown by 0.2s (min 1s)"
	upg.effect = knife_cooldown_upgrade
	available_perks.append(upg)
	var ek = Perk.new()
	ek.name = "Extra Knife"
	ek.description = "Throw one additional knife per attack (max 3)"
	ek.effect = extra_knife
	available_perks.append(ek)

func extra_knife():
	throwing_knife_count = min(throwing_knife_count + 1, 3)
	if throwing_knife_count < 3:
		var ek = Perk.new()
		ek.name = "Extra Knife"
		ek.description = "Throw one additional knife per attack (max 3)"
		ek.effect = extra_knife
		available_perks.append(ek)

func knife_cooldown_upgrade():
	throwing_knife_cooldown = maxf(1.0, throwing_knife_cooldown - 0.2)
	if throwing_knife_cooldown > 1.0:
		var upg = Perk.new()
		upg.name = "Knife Cooldown"
		upg.description = "Reduce throwing knife cooldown by 0.2s (min 1s)"
		upg.effect = knife_cooldown_upgrade
		available_perks.append(upg)

func _shoot_throwing_knife() -> void:
	for i in range(throwing_knife_count):
		var knife = throwing_knife.instantiate()
		knife.global_position = witch.global_position
		witch.get_parent().add_child(knife)

func unlock_spellbook() -> void:
	spellbook_count = 1
	_rebuild_spellbooks()
	var eb = Perk.new()
	eb.name = "Extra Book"
	eb.description = "Add another spellbook (max 5)"
	eb.effect = extra_book
	available_perks.append(eb)
	var fo = Perk.new()
	fo.name = "Faster Orbit"
	fo.description = "Spellbooks orbit the witch faster"
	fo.effect = faster_orbit
	available_perks.append(fo)
	var bd = Perk.new()
	bd.name = "Book Damage"
	bd.description = "Spellbooks deal 4 more damage"
	bd.effect = book_damage
	available_perks.append(bd)

func extra_book() -> void:
	spellbook_count = min(spellbook_count + 1, 5)
	_rebuild_spellbooks()
	if spellbook_count < 5:
		var eb = Perk.new()
		eb.name = "Extra Book"
		eb.description = "Add another spellbook (max 5)"
		eb.effect = extra_book
		available_perks.append(eb)

func faster_orbit() -> void:
	spellbook_speed += 0.5
	var fo = Perk.new()
	fo.name = "Faster Orbit"
	fo.description = "Spellbooks orbit the witch faster"
	fo.effect = faster_orbit
	available_perks.append(fo)

func book_damage() -> void:
	spellbook_damage += 4
	for book in _spellbooks:
		book.damage = spellbook_damage
	var bd = Perk.new()
	bd.name = "Book Damage"
	bd.description = "Spellbooks deal 4 more damage"
	bd.effect = book_damage
	available_perks.append(bd)

func _rebuild_spellbooks() -> void:
	for book in _spellbooks:
		book.queue_free()
	_spellbooks.clear()
	for i in range(spellbook_count):
		var book = spellbook_scene.instantiate()
		book.damage = spellbook_damage
		witch.get_parent().add_child(book)
		_spellbooks.append(book)