class_name TaskFindClosestBoatPart
extends Task

func run(blackboard: Dictionary) -> void:
    var world: World                  = blackboard["world"]
    var player: PlayerManager         = blackboard["player"]
    var navigation: TilemapNavigation = blackboard["navigation"]

    var parts: Array[Vector2i] = world.tilemap_interactive.get_cells_by_type_collection(
                                     tilemap_types.OBJECT_COLLECTION_BOAT_PARTS, player.board_position, player.view_distance)

    if len(parts) == 0:
        status = FAILURE
        status_reason = "No boat parts found"
        return

    var closest_part: Vector2i = navigation.manhattan_distance_closest(parts, player.board_position)
    player.player_memory["boat_part"] = closest_part
    StepVisualization.add_line_tileset(player.board_position, closest_part, StepVisualization.LineType.SEARCH_SELECTED)
    if closest_part == tilemap_types.NO_TILE_FOUND:
        status = FAILURE
        status_reason = "No closest boat part found"
        return

    blackboard["closest_part"] = closest_part

    var path: Array[Vector2i] = navigation.find_path_allow_neighbors(player.board_position, closest_part, player.view_distance)
    if path.size() > 0:
        blackboard["path"] = path
        status_reason = "Found path to closest boat part"
        status = SUCCESS
        return

    status = FAILURE
    status_reason = "No path found to closest boat part " + str(closest_part)